mirror of
https://github.com/followmsi/android_kernel_google_msm.git
synced 2024-11-06 23:17:41 +00:00
40faf463e6
There are situations in which the architecture wants to use the register that represents its word-size, whatever it is. For those, introduce __ASM_REG in asm.h, along with the first users _ASM_AX and _ASM_DX. They have users waiting for it, namely the getuser functions. Signed-off-by: Glauber Costa <gcosta@redhat.com> Signed-off-by: H. Peter Anvin <hpa@zytor.com> Signed-off-by: Ingo Molnar <mingo@elte.hu>
100 lines
1.9 KiB
ArmAsm
100 lines
1.9 KiB
ArmAsm
/*
|
|
* __get_user functions.
|
|
*
|
|
* (C) Copyright 1998 Linus Torvalds
|
|
* (C) Copyright 2005 Andi Kleen
|
|
*
|
|
* These functions have a non-standard call interface
|
|
* to make them more efficient, especially as they
|
|
* return an error value in addition to the "real"
|
|
* return value.
|
|
*/
|
|
|
|
/*
|
|
* __get_user_X
|
|
*
|
|
* Inputs: %rax contains the address.
|
|
* The register is modified, but all changes are undone
|
|
* before returning because the C code doesn't know about it.
|
|
*
|
|
* Outputs: %rax is error code (0 or -EFAULT)
|
|
* %rdx contains zero-extended value
|
|
*
|
|
*
|
|
* These functions should not modify any other registers,
|
|
* as they get called from within inline assembly.
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <asm/dwarf2.h>
|
|
#include <asm/page.h>
|
|
#include <asm/errno.h>
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/thread_info.h>
|
|
#include <asm/asm.h>
|
|
|
|
.text
|
|
ENTRY(__get_user_1)
|
|
CFI_STARTPROC
|
|
GET_THREAD_INFO(%_ASM_DX)
|
|
cmp TI_addr_limit(%_ASM_DX),%_ASM_AX
|
|
jae bad_get_user
|
|
1: movzb (%_ASM_AX),%edx
|
|
xor %eax,%eax
|
|
ret
|
|
CFI_ENDPROC
|
|
ENDPROC(__get_user_1)
|
|
|
|
ENTRY(__get_user_2)
|
|
CFI_STARTPROC
|
|
add $1,%_ASM_AX
|
|
jc bad_get_user
|
|
GET_THREAD_INFO(%_ASM_DX)
|
|
cmp TI_addr_limit(%_ASM_DX),%_ASM_AX
|
|
jae bad_get_user
|
|
2: movzwl -1(%_ASM_AX),%edx
|
|
xor %eax,%eax
|
|
ret
|
|
CFI_ENDPROC
|
|
ENDPROC(__get_user_2)
|
|
|
|
ENTRY(__get_user_4)
|
|
CFI_STARTPROC
|
|
add $3,%_ASM_AX
|
|
jc bad_get_user
|
|
GET_THREAD_INFO(%_ASM_DX)
|
|
cmp TI_addr_limit(%_ASM_DX),%_ASM_AX
|
|
jae bad_get_user
|
|
3: mov -3(%_ASM_AX),%edx
|
|
xor %eax,%eax
|
|
ret
|
|
CFI_ENDPROC
|
|
ENDPROC(__get_user_4)
|
|
|
|
ENTRY(__get_user_8)
|
|
CFI_STARTPROC
|
|
add $7,%_ASM_AX
|
|
jc bad_get_user
|
|
GET_THREAD_INFO(%_ASM_DX)
|
|
cmp TI_addr_limit(%_ASM_DX),%_ASM_AX
|
|
jae bad_get_user
|
|
4: movq -7(%_ASM_AX),%_ASM_DX
|
|
xor %eax,%eax
|
|
ret
|
|
CFI_ENDPROC
|
|
ENDPROC(__get_user_8)
|
|
|
|
bad_get_user:
|
|
CFI_STARTPROC
|
|
xor %edx,%edx
|
|
mov $(-EFAULT),%_ASM_AX
|
|
ret
|
|
CFI_ENDPROC
|
|
END(bad_get_user)
|
|
|
|
.section __ex_table,"a"
|
|
.quad 1b,bad_get_user
|
|
.quad 2b,bad_get_user
|
|
.quad 3b,bad_get_user
|
|
.quad 4b,bad_get_user
|
|
.previous
|