mirror of
https://github.com/team-infusion-developers/android_kernel_samsung_msm8976.git
synced 2024-09-21 03:43:03 +00:00
59180ec546
commit 23e94994464a7281838785675e09c8ed1055f62f upstream. The AArch64 instruction set contains load/store pair memory accessors, so use these in our copy_*_user routines to transfer 16 bytes per iteration. Change-Id: Ie9874b067ff7450a40b29a760f0c6e742f750adc Reviewed-by: Catalin Marinas <catalin.marinas@arm.com> Signed-off-by: Will Deacon <will.deacon@arm.com> Signed-off-by: David Brown <david.brown@linaro.org>
67 lines
1.5 KiB
ArmAsm
67 lines
1.5 KiB
ArmAsm
/*
|
|
* Copyright (C) 2012 ARM Ltd.
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License version 2 as
|
|
* published by the Free Software Foundation.
|
|
*
|
|
* This program is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with this program. If not, see <http://www.gnu.org/licenses/>.
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <asm/assembler.h>
|
|
|
|
/*
|
|
* Copy to user space from a kernel buffer (alignment handled by the hardware)
|
|
*
|
|
* Parameters:
|
|
* x0 - to
|
|
* x1 - from
|
|
* x2 - n
|
|
* Returns:
|
|
* x0 - bytes not copied
|
|
*/
|
|
ENTRY(__copy_to_user)
|
|
add x5, x0, x2 // upper user buffer boundary
|
|
subs x2, x2, #16
|
|
b.mi 1f
|
|
0:
|
|
ldp x3, x4, [x1], #16
|
|
subs x2, x2, #16
|
|
USER(9f, stp x3, x4, [x0], #16)
|
|
b.pl 0b
|
|
1: adds x2, x2, #8
|
|
b.mi 2f
|
|
ldr x3, [x1], #8
|
|
sub x2, x2, #8
|
|
USER(9f, str x3, [x0], #8 )
|
|
2: adds x2, x2, #4
|
|
b.mi 3f
|
|
ldr w3, [x1], #4
|
|
sub x2, x2, #4
|
|
USER(9f, str w3, [x0], #4 )
|
|
3: adds x2, x2, #2
|
|
b.mi 4f
|
|
ldrh w3, [x1], #2
|
|
sub x2, x2, #2
|
|
USER(9f, strh w3, [x0], #2 )
|
|
4: adds x2, x2, #1
|
|
b.mi 5f
|
|
ldrb w3, [x1]
|
|
USER(9f, strb w3, [x0] )
|
|
5: mov x0, #0
|
|
ret
|
|
ENDPROC(__copy_to_user)
|
|
|
|
.section .fixup,"ax"
|
|
.align 2
|
|
9: sub x0, x5, x0 // bytes not copied
|
|
ret
|
|
.previous
|